PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX sioc:  <http://rdfs.org/sioc/ns#>
PREFIX ltlod: <http://linkeddata.lt/ns#>

SELECT DISTINCT ?person
WHERE
  { GRAPH ?graph
      { ?doc  sioc:has_container  $this ;
              foaf:primaryTopic   ?person .
        ?person  a                  foaf:Person ;
                 foaf:givenName     ?givenName ;
                 foaf:familyName    ?familyName .
        OPTIONAL
          { ?person  foaf:gender  ?gender }
        OPTIONAL
          { ?person  ltlod:nominatedBy  ?party }
      }
  }
ORDER BY ?familyName ?givenName

PREFIX epvoc: <https://data.europarl.europa.eu/def/epvoc#>
PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX org:   <http://www.w3.org/ns/org#>
PREFIX skos:  <http://www.w3.org/2004/02/skos/core#>
PREFIX time:  <http://www.w3.org/2006/time#>

# Everyone who held a seat during the term (epvoc:memberDuringParliamentaryTerm is on the
# Seimas seat memberships only), as a percentage with one decimal; ordered by term start.
SELECT ?kadencija (ROUND(1000 * SUM(?female) / COUNT(?person)) / 10 AS ?moterys_proc)
WHERE
{
    {
        SELECT DISTINCT ?term ?person ?gender
        WHERE
        {
            GRAPH ?personGraph
            {
                ?membership epvoc:memberDuringParliamentaryTerm ?term ;
                    org:member ?person .
                ?person foaf:gender ?gender .
            }
        }
    }
    BIND(IF(?gender = "female", 1, 0) AS ?female)
    GRAPH ?termGraph
    {
        ?term skos:prefLabel ?label ;
            time:hasTime/time:hasBeginning/time:inXSDDate ?start .
    }
    BIND(REPLACE(STR(?label), " metų kadencija", "") AS ?kadencija)
}
GROUP BY ?start ?kadencija
ORDER BY ?start