Category variable name
nugaletojas
Chart type
Series variable name
kadencijos
Title
Most re-elected in the same constituencyen
Daugiausia kartų toje pačioje apygardoje išrinktilt
Text
PREFIX epvoc: <https://data.europarl.europa.eu/def/epvoc#>
PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX org:   <http://www.w3.org/ns/org#>
PREFIX skos:  <http://www.w3.org/2004/02/skos/core#>
PREFIX ltlod: <http://linkeddata.lt/ns#>

# A constituency is a per-term document (constituencies/{term}-{number}/), so "the same
# constituency" is the same name across terms; numbers were reassigned between elections.
SELECT ?nugaletojas (COUNT(DISTINCT ?term) AS ?kadencijos)
WHERE
{
    GRAPH ?personGraph
    {
        ?membership ltlod:electoralDistrict ?district ;
            org:member ?person ;
            epvoc:memberDuringParliamentaryTerm ?term .
        ?person foaf:name ?vardas .
    }
    GRAPH ?districtGraph { ?district skos:prefLabel ?name }
    BIND(CONCAT(?vardas, " (", STR(?name), ")") AS ?nugaletojas)
}
GROUP BY ?nugaletojas
HAVING (COUNT(DISTINCT ?term) >= 4)
ORDER BY DESC(?kadencijos) ?nugaletojas
Title
Seimas members by terms won in the same constituencyen
Seimo nariai pagal kadencijas toje pačioje apygardojelt