PREFIX dct:    <http://purl.org/dc/terms/>
PREFIX schema: <https://schema.org/>
PREFIX time:   <http://www.w3.org/2006/time#>

# VALUES fixes the Monday-first order and the Lithuanian weekday names.
SELECT ?diena (COUNT(DISTINCT ?sitting) AS ?posedziai)
WHERE
{
    VALUES (?weekday ?order ?diena)
    {
        (time:Monday 1 "Pirmadienis") (time:Tuesday 2 "Antradienis") (time:Wednesday 3 "Trečiadienis")
        (time:Thursday 4 "Ketvirtadienis") (time:Friday 5 "Penktadienis") (time:Saturday 6 "Šeštadienis")
        (time:Sunday 7 "Sekmadienis")
    }
    GRAPH ?sittingGraph
    {
        ?sitting a schema:Event ;
            dct:temporal ?day .
    }
    GRAPH ?dayGraph { ?day time:hasDateTimeDescription/time:dayOfWeek ?weekday }
}
GROUP BY ?order ?diena
ORDER BY ?order

PREFIX dct:  <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX sioc: <http://rdfs.org/sioc/ns#>
PREFIX time: <http://www.w3.org/2006/time#>

SELECT DISTINCT ?year
WHERE
  { GRAPH ?graph
      { ?doc  sioc:has_container  $this ;
              foaf:primaryTopic   ?year .
        ?year  time:hasDateTimeDescription/time:unitType  time:unitYear ;
               dct:identifier  ?id
      }
  }
ORDER BY DESC(?id)